mediaで炎

非常に細かい粒子を表現するmedia機能を用いて、ちょっとリアルな炎の作成方法を説明します。
出来上がる画像は次のような感じです。

構成としてはmediaを使用した炎の interior{} を指定する Media_Fire と、炎の形を生成する Fireマクロ に分かれます。
そして、上記画像を生成したソースコードは次のようになります。コピー＆ペーストで使用してください。

// ========================================================
// File:            media_fire.pov
// POV-Ray Vers:    3.5
// Desc:            Media Fire Macro Scene
// Date:            2003-09-09
// Author:          mak fukui [ mak@neodrive.net ]
// ========================================================

#version 3.5;
global_settings{
	// Fireマクロを使う場合はmax_trace_levelを上げる必要があります
	max_trace_level 50
}

camera{
	location <0,4,-15>
	look_at y*4
	angle 70
	right x*image_width/image_height
}

light_source{ < 1000,0,-1000> rgb 0.8 }
light_source{ <-1000,0,-1000> rgb 0.8 }

#declare Media_Fire = interior {
	media {
		method 3
		emission 1                 // ここで全体の明るさを調節
		intervals 50               // 光線の長さです。この値を大きくすると綺麗になるようです。
		samples 1, 1               // intervals同様この値を大きくすると綺麗になります。
		confidence 0.9999          // ここはイマイチ不明です。品質を調整するそうなのですが・・・
		variance 1/100             // ここも同じようです。数字が小さいほうが綺麗になるようです。
		ratio 0.9                  // ここも不明です。まぁ適当に。
		density {
			bozo                   // パターンを代えると面白いかもしれません。
			turbulence 1           // このあたりは自由に変更してください。
			color_map {
				[ 0.00 color rgb 0 ]
				[ 0.10 color rgb <0.9435,0.6552,0.1124> ]    // 黄色っぽい色
				[ 0.16 color rgb <0.8983,0.1423,0.0353> ]    // 赤色っぽい色
				[ 0.28 color rgb <0.9799,0.7142,0.6143> ]    // 白色っぽい色
				[ 0.32 color rgb <0.9912,0.2643,0.0163> ]    // 赤色っぽい色
				[ 0.42 color rgb <0.9912,0.4643,0.1356> ]    // 黄色っぽい色
				[ 0.48 color rgb <0.9553,0.1234,0.0282> ]    // 赤色っぽい色
				[ 0.50 color rgb 0 ]
				[ 1.00 color rgb 0 ]
			}
		}
	}
}    


#macro Fire(Width,Height,Wind_x,Wind_z)    // (最大横幅、最大高さ、x方向の風によるずれ、同z方向のずれ)
	#local R1 = seed(1234);                // 乱数の種
	#local R2 = seed(5678);
	
	merge{                                 // unionではうまくいかないようです。
		#local C = 0;#while( C < Height )                   
			#local max_Width = sin(C*(pi/Height))*Width;    // 各高さにおける横方向の最大値です。
			#local y_move = C*C/Height;                     // 高さの宣言です。
			#local Wind_x_move = y_move*(Wind_x/Height);    // x方向への風のずれです。
			#local Wind_z_move = y_move*(Wind_z/Height);    // 同じくz方向への風のずれです。
			
			#local C2 = 0;#while (C2 <= 2*pi )
				#local x_move = rand(R1)*max_Width*cos(C2); // x方向の位置
				#local z_move = rand(R2)*max_Width*sin(C2); // z方向の位置
				
				sphere{<0,0,0>,0.5
					// 各位置と風によるずれ 
					translate <x_move+Wind_x_move,y_move,z_move+Wind_z_move> 
				}

				#local C2 = C2 + 0.3;	// この値を小さくすることによって配置する球の数が増えます。
			#end      
		#local C = C+0.2;        
		#end
	}                
#end

object { Fire(3,10,2,2) pigment { rgbf 1 } hollow on interior { Media_Fire } }

レンダリング時間等は次のようになっています。（Pentium4 2.6CGHz, 1GB RAM）

Resolution 512 x 384, AA 0.3
----------------------------------------------------------------------------
Pixels:          197120   Samples:          231048   Smpls/Pxl: 1.17
Rays:            411106   Saved:                 0   Max Level: 13/50
----------------------------------------------------------------------------
Ray->Shape Intersection          Tests       Succeeded  Percentage
----------------------------------------------------------------------------
CSG Merge                      1151690          623914     54.17
Sphere                      1233459990         6192137      0.50
----------------------------------------------------------------------------
Calls to Noise:           22457728   Calls to DNoise:      157204106
----------------------------------------------------------------------------
Media Intervals:           4490600   Media Samples:         22457728 (5.00)
Shadow Ray Tests:           740584   Succeeded:               443856
Transmitted Rays:           180058
----------------------------------------------------------------------------
Smallest Alloc:                 25 bytes   Largest:            12056
Peak memory used:           632194 bytes
----------------------------------------------------------------------------
Time For Trace:    0 hours  4 minutes  19.0 seconds (259 seconds)
    Total Time:    0 hours  4 minutes  19.0 seconds (259 seconds)
----------------------------------------------------------------------------
CPU time used: kernel 2.27 seconds, user 254.36 seconds, total 256.63 seconds
Render averaged 766.13 PPS over 196608 pixels

POV-Ray finished

 

 

	このサイトに対するご意見・ご感想をお聞かせください。 下記フォームあるいはF.T.Bから気軽に投稿してください。 あなたの名前： Eメールアドレス： （名前・メールアドレスは、いずれも未記入でも構いません）